Direkt zum Inhalt

Cookie-Einstellungen

Wählen Sie, welche Arten von Cookies Sie erlauben. Sie können Ihre Auswahl jederzeit über Cookie-Einstellungen unten auf jeder Seite ändern. Datenschutzerklärung

Notwendig

Immer aktiv

Nötig zum Einloggen, für Ihren Warenkorb und um Ihre Auswahl zu speichern. Diese sind immer aktiv.

Welche Cookies?
  • weboke_sessie, weboke_klant, weboke_remember: Ihre Sitzung und eingeloggt bleiben
  • weboke_basket: Ihr Warenkorb
  • wkBtwIncl: Preise mit oder ohne MwSt. anzeigen
  • wok_cookies: Ihre Cookie-Auswahl, 12 Monate

Misst, welche Anzeige zu einem Besuch oder einer Bestellung führt, damit wir nicht für Anzeigen zahlen, die nichts bringen.

Welche Cookies?
  • Google Ads über Google Tag Manager (_gcl_au, _gcl_aw), bis zu 90 Tage
  • OpenAI Ads, Anzeigen in ChatGPT
  • wok_aff: über welchen Partner Sie zu uns kamen (Partnerprogramm), 60 Tage

4,6

Land und Sprache

Jedes Land hat seine eigene Website, mit Preisen und MwSt. dieses Landes.

Anzeigen

Kalenderwochen nach europäischer Zählung, auch um den Jahreswechsel

Eine Produktionsplanung, ein Dienstplan oder eine Umsatzübersicht pro Woche: In Deutschland und den meisten europäischen Ländern zählen Sie Wochen nach der europäischen Norm (ISO 8601). Woche 1 ist die Woche mit dem ersten Donnerstag des Jahres, und eine Woche beginnt am Montag. Die Funktion KALENDERWOCHE zählt standardmäßig nach amerikanischer Art: Woche 1 ist die Woche des 1. Januar, und eine Woche beginnt am Sonntag. Den größten Teil des Jahres macht das eine Woche oder gar nichts aus, aber um den Jahreswechsel geht es schief. Und 2026 ist so ein Jahr: Es hat 53 Wochen.

Als Beispiel verwenden wir die Produktionsplanung der Bakkerij De Korenaar, mit Datumsangaben rund um Weihnachten und Silvester in Spalte A.

Der Unterschied in einer Tabelle

Datum=KALENDERWOCHE(A2)=ISOKALENDERWOCHE(A2)Wochenjahr
Fr 25-12-202652522026
Mo 28-12-202653532026
Fr 01-01-20271532026
So 03-01-20272532026
Mo 04-01-2027212027

Freitag, der 1. Januar 2027, gehört nach der europäischen Zählung noch zu Woche 53 von 2026. Die amerikanische Zählung macht daraus Woche 1 und Sonntag, den 3. Januar, sogar schon Woche 2.

Kalenderwochen um den Jahreswechsel
KALENDERWOCHE (1) zählt amerikanisch, ISOKALENDERWOCHE (2) europäisch; das Wochenjahr (3) bleibt 2026 bis einschließlich Sonntag, 3. Januar. Rechts die Hilfsformeln aus der Tabelle unten

Schritt 1: die richtige Kalenderwoche

Geben Sie in B2 =ISOKALENDERWOCHE(A2) ein und ziehen Sie die Formel nach unten. Sie können auch =KALENDERWOCHE(A2;21) verwenden: Die Zahl 21 als zweites Argument steht ebenfalls für die europäische Zählung. Das ist praktisch, wenn ein Kollege die Datei in einer alten Excel-Version öffnet, die ISOKALENDERWOCHE nicht kennt.

Schritt 2: das richtige Jahr zur Kalenderwoche

Wenn Sie Woche und Jahr zusammensetzen, geht es mit =JAHR(A2) schief: Der 1. Januar 2027 wird dann zu „Woche 53 von 2027“, einer Woche, die es nicht gibt. Das Wochenjahr ist das Jahr des Donnerstags in derselben Woche:

=JAHR(A2-WOCHENTAG(A2;2)+4)

WOCHENTAG(A2;2) liefert 1 für Montag bis 7 für Sonntag. A2 minus Wochentag plus 4 ist also der Donnerstag dieser Woche, und dessen JAHR ist das Wochenjahr.

Schritt 3: ein sortierbares Label

Für eine Übersicht oder eine Pivot-Tabelle pro Woche ist ein Label wie 2026-W53 praktisch: Es sortiert sich von selbst richtig, auch über die Jahresgrenze hinweg.

=JAHR(A2-WOCHENTAG(A2;2)+4)&"-W"&TEXT(ISOKALENDERWOCHE(A2);"00")

TEXT mit "00" setzt bei Wochen unter 10 eine Null davor, sodass Woche 2 als W02 vor W10 kommt.

Nützliche Formeln für eine Wochenplanung

WasFormelBeispiel
Montag der Woche=A2-WOCHENTAG(A2;2)+101-01-2027 ergibt 28-12-2026
Sonntag der Woche=A2-WOCHENTAG(A2;2)+701-01-2027 ergibt 03-01-2027
Montag der Woche 10 von 2027=DATUM(2027;1;4)-WOCHENTAG(DATUM(2027;1;4);2)+1+(10-1)*708-03-2027
Letzter Tag des Monats=MONATSENDE(A2;0)25-12-2026 ergibt 31-12-2026
Erster Tag des Monats=MONATSENDE(A2;-1)+125-12-2026 ergibt 01-12-2026

Sehen Sie eine Zahl wie 46387 statt eines Datums, geben Sie der Zelle ein Datumsformat (siehe Zahlen, Datumswerte und Währungen formatieren). MONATSENDE und ein berechnetes Datum erhalten dieses nicht immer automatisch.

Die Formel für den Montag einer bestimmten Woche funktioniert so: Der 4. Januar liegt immer in Woche 1. Ab dem Montag dieser Woche zählen Sie (Woche minus 1) mal 7 Tage hinzu. Wenn Sie das Jahr und die Kalenderwoche in eigene Zellen schreiben, ersetzen Sie 2027 und 10 durch diese Zellen.

Umsatz pro Woche

Setzen Sie das Wochenlabel aus Schritt 3 in eine Hilfsspalte neben Ihre Verkaufsdaten. Danach können Sie mit SUMMEWENNS auf diese Hilfsspalte pro Woche summieren (siehe Umsatz pro Monat oder Zeitraum mit SUMMEWENNS addieren) oder die Hilfsspalte in einer Pivot-Tabelle unter Zeilen einfügen. Das Gruppieren nach 7 Tagen in einer Pivot-Tabelle ergibt keine ISO-Wochen: siehe Eine Pivot-Tabelle nach Monat, Quartal oder Woche.

Stolperfallen

  • =KALENDERWOCHE(A2;2) lässt die Woche zwar am Montag beginnen, zählt aber weiterhin ab dem 1. Januar. Das ist also keine europäische Zählung: Der 1. Januar 2027 wird zu Woche 1. Verwenden Sie 21, nicht 2.
  • Ein Jahr hat 52 oder 53 Wochen. Legen Sie eine Planung also nicht fest auf 52 Wochen aus.
  • Steht das Datum als Text in der Zelle (linksbündig), liefert die Formel #WERT!. Wandeln Sie die Datumsangaben zuerst um: siehe Datums, die als Text ankommen oder bei denen Tag und Monat vertauscht sind.

Einen Moment bitte…

Richten Sie Ihre Domains ein

Legen Sie für jede Domain die Nameserver, die Verknüpfung mit Ihrem Hosting und den künftigen Inhaber fest.

Ihre Domains werden geladen…