Direkt zum Inhalt

Cookie-Einstellungen

Wählen Sie, welche Arten von Cookies Sie erlauben. Sie können Ihre Auswahl jederzeit über Cookie-Einstellungen unten auf jeder Seite ändern. Datenschutzerklärung

Notwendig

Immer aktiv

Nötig zum Einloggen, für Ihren Warenkorb und um Ihre Auswahl zu speichern. Diese sind immer aktiv.

Welche Cookies?
  • weboke_sessie, weboke_klant, weboke_remember: Ihre Sitzung und eingeloggt bleiben
  • weboke_basket: Ihr Warenkorb
  • wkBtwIncl: Preise mit oder ohne MwSt. anzeigen
  • wok_cookies: Ihre Cookie-Auswahl, 12 Monate

Misst, welche Anzeige zu einem Besuch oder einer Bestellung führt, damit wir nicht für Anzeigen zahlen, die nichts bringen.

Welche Cookies?
  • Google Ads über Google Tag Manager (_gcl_au, _gcl_aw), bis zu 90 Tage
  • OpenAI Ads, Anzeigen in ChatGPT
  • wok_aff: über welchen Partner Sie zu uns kamen (Partnerprogramm), 60 Tage

4,6

Land und Sprache

Jedes Land hat seine eigene Website, mit Preisen und MwSt. dieses Landes.

Anzeigen

Umsatz pro Monat oder Zeitraum mit SUMMEWENNS addieren

Ein Kassenbuch, eine Verkaufsliste oder eine Zeiterfassung enthält pro Zeile ein Datum. Was Sie wissen möchten, ist die Summe pro Monat, pro Quartal oder zwischen zwei Daten, eventuell zusätzlich pro Produkt. Mit SUMMEWENNS und zwei Datumsbedingungen erstellen Sie eine solche Übersicht, und sie stimmt auch dann noch, wenn Zeilen hinzukommen. Eine Pivot-Tabelle kann das ebenfalls (siehe Eine Pivot-Tabelle nach Monat, Quartal oder Woche); SUMMEWENNS ist praktischer, wenn die Übersicht eine feste Form behalten soll, zum Beispiel für einen Bericht oder ein Budget.

Als Beispiel nehmen wir die Verkäufe der Bloemisterij Het Zonnetje auf dem Arbeitsblatt Verkoop: in A das Datum, in B das Produkt, in C die Kategorie und in D der Betrag, von Zeile 2 bis einschließlich 300.

Schritt 1: eine Spalte mit Monaten

Erstellen Sie ein Arbeitsblatt Übersicht. Statt zwölf Daten einzutippen, erzeugt eine einzige Formel sie alle. Geben Sie in A2 ein:

=EDATUM(DATUM(2026;1;1);SEQUENZ(12;1;0))

SEQUENZ(12;1;0) erzeugt die Zahlen 0 bis 11, und EDATUM addiert entsprechend viele Monate zum 1. Januar 2026. Sie erhalten den ersten Tag jedes Monats, von A2 bis einschließlich A13. Weisen Sie A2:A13 das benutzerdefinierte Format MMMM JJJJ zu (über Weitere Formate, Benutzerdefiniert, siehe Eigene Zahlenformate: „12 Stk“, Beträge in Tausend, Rot bei negativen Werten), dann steht dort Januar 2026, Februar 2026 und so weiter.

Das Datumsformat MMMM JJJJ
Das benutzerdefinierte Format MMMM JJJJ zeigt den Monat ausgeschrieben mit dem Jahr

Schritt 2: der Umsatz pro Monat

Geben Sie in B2 ein:

=SUMMEWENNS(Verkoop!$D$2:$D$300;Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&MONATSENDE($A2;0))

SUMMEWENNS addiert die Beträge, bei denen das Datum größer oder gleich dem ersten Tag des Monats und kleiner oder gleich dem letzten Tag ist (MONATSENDE mit 0 liefert das Ende desselben Monats). Ziehen Sie die Formel bis B13 herunter, oder markieren Sie B2:B13, bevor Sie tippen, und schließen Sie mit Strg+Enter ab.

Schritt 3: pro Produkt

Setzen Sie Produktnamen als Überschriften nebeneinander, zum Beispiel Rozen in C1, Tulpen in D1 und Boeket in E1, und geben Sie in C2 ein:

=SUMMEWENNS(Verkoop!$D$2:$D$300;Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&MONATSENDE($A2;0);Verkoop!$B$2:$B$300;C$1)

Es kommt ein Bedingungspaar hinzu: Das Produkt muss der Überschrift entsprechen. Achten Sie auf die Dollarzeichen: $A2 fixiert die Spalte mit den Monaten, C$1 die Zeile mit den Überschriften. Dadurch kann dieselbe Formel im gesamten Bereich stehen. Schneller geht es so: Markieren Sie zuerst C2:E13, geben Sie die Formel ein und drücken Sie Strg+Enter. Euro-Office setzt die Formel dann in alle markierten Zellen, wobei die Bezüge für jede Zelle angepasst werden.

Umsatz pro Monat und pro Produkt
Pro Monat und pro Produkt addiert. In der Bearbeitungsleiste die Formel aus C2, die mit C$1 auf die Überschrift Rozen (1) verweist

Zählen statt addieren

Die Anzahl der Verkäufe pro Monat zählen Sie mit denselben Bedingungen und ZÄHLENWENNS:

=ZÄHLENWENNS(Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&MONATSENDE($A2;0))

Ein frei wählbarer Zeitraum

Tragen Sie ein Anfangsdatum in H1 und ein Enddatum in I1 ein. Der Umsatz dazwischen, beide Tage eingeschlossen:

=SUMMEWENNS(Verkoop!D:D;Verkoop!A:A;">="&H1;Verkoop!A:A;"<="&I1)

Stolperfallen

  • Anführungszeichen und &: Der Vergleich steht in Anführungszeichen und die Zelle wird mit & dahinter angehängt: ">="&H1. Geben Sie ">=H1" ein, sucht Euro-Office nach dem Text H1 und das Ergebnis ist 0.
  • Daten mit Uhrzeit (16.11.2026 14:32) fallen am letzten Tag des Monats aus "<="&MONATSENDE(...) heraus, denn dieser Wert steht für Mitternacht. Verwenden Sie dann als zweite Bedingung "<"&EDATUM($A2;1): kleiner als der erste Tag des Folgemonats.
  • Nur nach Monatsnummer zu filtern, zum Beispiel mit MONAT() in einer Hilfsspalte, zählt Januar 2025 und Januar 2026 zusammen. Beziehen Sie das Jahr immer mit ein.
  • Daten als Text werden nicht mitgezählt. Siehe Datums, die als Text ankommen oder bei denen Tag und Monat vertauscht sind.

Einen Moment bitte…

Richten Sie Ihre Domains ein

Legen Sie für jede Domain die Nameserver, die Verknüpfung mit Ihrem Hosting und den künftigen Inhaber fest.

Ihre Domains werden geladen…