Direkt zum Inhalt

Cookie-Einstellungen

Wählen Sie, welche Arten von Cookies Sie erlauben. Sie können Ihre Auswahl jederzeit über Cookie-Einstellungen unten auf jeder Seite ändern. Datenschutzerklärung

Notwendig

Immer aktiv

Nötig zum Einloggen, für Ihren Warenkorb und um Ihre Auswahl zu speichern. Diese sind immer aktiv.

Welche Cookies?
  • weboke_sessie, weboke_klant, weboke_remember: Ihre Sitzung und eingeloggt bleiben
  • weboke_basket: Ihr Warenkorb
  • wkBtwIncl: Preise mit oder ohne MwSt. anzeigen
  • wok_cookies: Ihre Cookie-Auswahl, 12 Monate

Misst, welche Anzeige zu einem Besuch oder einer Bestellung führt, damit wir nicht für Anzeigen zahlen, die nichts bringen.

Welche Cookies?
  • Google Ads über Google Tag Manager (_gcl_au, _gcl_aw), bis zu 90 Tage
  • OpenAI Ads, Anzeigen in ChatGPT
  • wok_aff: über welchen Partner Sie zu uns kamen (Partnerprogramm), 60 Tage

4,6

Land und Sprache

Jedes Land hat seine eigene Website, mit Preisen und MwSt. dieses Landes.

Anzeigen

Zwei Listen vergleichen: Wer steht in der einen und nicht in der anderen?

Die Mitgliederliste gegen die Zahlungen, die Kunden des Vorjahres gegen die dieses Jahres, die Bestandsliste gegen die Bestellung: Sie möchten wissen, wer in der einen Liste steht und nicht in der anderen. Doppelte Kunden finden und entfernen sucht Duplikate innerhalb einer Liste; hier vergleichen Sie zwei Listen miteinander.

Als Beispiel nehmen wir die Bakkerij De Korenaar mit zwei Arbeitsblättern: Klanten2025 mit den E-Mail-Adressen des Vorjahres in A2:A8 und Klanten2026 mit denen dieses Jahres in A2:A7.

Methode 1: eine Hilfsspalte mit weg oder bleibt

Geben Sie auf dem Arbeitsblatt Klanten2025 in B2 ein:

=WENN(ZÄHLENWENN(Klanten2026!$A$2:$A$7;A2)=0;"weg";"bleibt")

Ziehen Sie die Formel bis zum letzten Kunden nach unten. ZÄHLENWENN zählt, wie oft die Adresse in der Liste von 2026 vorkommt. Ist das 0, ist der Kunde weg. Anschließend können Sie nach Spalte B filtern oder sortieren (siehe Sortieren und Filtern).

Die Dollarzeichen sind wichtig: Ohne Dollarzeichen verschiebt sich der Bereich in der anderen Liste beim Herunterziehen mit, und die oberen Adressen fallen heraus.

Methode 2: eine Liste nur mit den Unterschieden

Auf einem separaten Arbeitsblatt erstellt FILTER in einem Schritt eine Liste aller abgewanderten Kunden:

=FILTER(Klanten2025!A2:A8;ZÄHLENWENN(Klanten2026!A2:A7;Klanten2025!A2:A8)=0;"niemand weg")

Hier erhält ZÄHLENWENN eine ganze Liste als zweites Argument und zählt für jede Adresse von 2025 gleichzeitig. FILTER behält die Adressen, bei denen das Ergebnis 0 ist. Die neuen Kunden finden Sie, indem Sie die Listen vertauschen:

=FILTER(Klanten2026!A2:A7;ZÄHLENWENN(Klanten2025!A2:A8;Klanten2026!A2:A7)=0;"niemand neu")

Abgewanderte und neue Kunden nebeneinander
Abgewanderte Kunden (1) und neue Kunden (2), jeweils mit einer FILTER-Formel

Wer nur in einer der beiden Listen steht, ob neu oder abgewandert, erhalten Sie mit:

=EINDEUTIG(VSTAPELN(Klanten2025!A2:A8;Klanten2026!A2:A7);;1)

VSTAPELN setzt die beiden Listen untereinander. EINDEUTIG mit einer 1 als drittem Argument behält nur die Werte, die genau einmal vorkommen. Steht eine Adresse bereits innerhalb einer Liste doppelt, machen Sie diese Liste zuerst eindeutig: =EINDEUTIG(VSTAPELN(EINDEUTIG(Klanten2025!A2:A8);EINDEUTIG(Klanten2026!A2:A7));;1).

Methode 3: Farben statt Listen

  1. Markieren Sie auf dem Arbeitsblatt Klanten2025 die Adressen, A2:A8.
  2. Wählen Sie auf der Registerkarte Startseite Bedingte Formatierung, Neue Regel, Typ Formel.
  3. Geben Sie =ZÄHLENWENN(Klanten2026!$A$2:$A$7;$A2)=0 ein, wählen Sie eine Füllfarbe und klicken Sie auf OK.

Ein Bezug auf ein anderes Arbeitsblatt in einer Formatierungsregel funktioniert in Euro-Office problemlos; in alten Excel-Versionen war dafür ein benannter Bereich nötig.

Abgewanderte Kunden farbig markiert
Adressen, die 2026 nicht mehr vorkommen, werden orange; Spalte B zeigt weg oder bleibt

Stolperfallen

  • Leerzeichen: "info@dekorenaar.nl " mit einem Leerzeichen am Ende ist für die Tabelle eine andere Adresse. Entfernen Sie Leerzeichen zuerst mit GLÄTTEN in einer Hilfsspalte.
  • Leere Zellen in einem Bereich zählen ebenfalls als Wert. Nehmen Sie also nur die Zeilen mit Daten oder filtern Sie leere Zellen mit <>"" heraus.
  • Zahlen gegen Text: Wenn Sie Kundennummern vergleichen und die Nummer in der einen Liste als Text (links in der Zelle) und in der anderen als Zahl steht, finden sie sich nicht. Siehe SVERWEIS gibt #NV zurück: so lösen Sie das Problem.
  • Geben Sie kein WAHR ohne Klammern als drittes Argument von EINDEUTIG ein; Euro-Office akzeptiert nur TRUE, WAHR() oder 1 (siehe Formeln aus Excel übernehmen: deutsche Funktionsnamen und das Semikolon).

Einen Moment bitte…

Richten Sie Ihre Domains ein

Legen Sie für jede Domain die Nameserver, die Verknüpfung mit Ihrem Hosting und den künftigen Inhaber fest.

Ihre Domains werden geladen…